In einer TOTALCOLUMNTABLE können die TOTALCOLUMNs mehrerer Tabellen in einer Übersichtstabelle nebeneinander dargestellt werden.
Enthält eine TOTALCOLUMNTABLE nur ein CELLELEMENT, kann diese als Grundlage für die Charterstellung mittels GESStabs Artist und GESS ChartFactory herangezogen werden.
Das folgende Skript tabelliert elf Einzeltabellen über elf Variablen zur Bewertung verschiedener Aspekte eines PKW. Zur Struktur des Skripts: Das Iterator-Makro '#iter' stellt die Assoziation von Namen zu den Variablennummer her. z1 steht für die Vorderansicht, z8 für den Frontspoiler usw. '#iter' wird zweimal verwendet, einmal mit dem Macro 't' zur Anfertigung der elf Tabellen, und einmal mit dem Macro 'tc' zur Beschreibung der elf Spalten der TOTALCOLUMNTABLE.
#macro #iter( &name )
#&name( 1 "Vorder~ansicht" )
#&name( 2 "Rückansicht" )
#&name( 3 "Schein~werfer" )
#&name( 4 "Innen~ausstattung" )
#&name( 5 "Entertain~ment" )
#&name( 6 "Ansicht von der Seite" )
#&name( 7 "Farbe" )
#&name( 8 "Frontspoiler" )
#&name( 9 "Sitze (Seiten~führung)" )
#&name( 10 "Rück~spiegel außen" )
#&name( 11 "Rück~spiegel innen" )
#endmacro
LABELS z1 TO z11 =
OVERCODE 1:2 "sehr gut, gut"
1 "sehr gut"
2 "gut"
3 "teils/teils"
4 "schlecht"
5 "sehr schlecht"
OVERCODE 4:5 "schlecht, sehr schlecht"
;
CELLELEMENTS = COLUMNPERCENT ABSOLUTE;
FRAMEELEMENTS = TOTALCOLUMN ABSROW;
#macro #t( &1 &2 )
VARTITLE z&1 = "Zufriedenheit mit &2";
TABLETITLE = "Tabelle zu &2";
TABLE NAME t&1 = k BY z&1 MEAN : DESCRIPTION Mean( z&1 ) HYTTEST( z&1 ); TOPTEXT = "
Wie zufrieden sind Sie mit ...
";
#endmacro
#iter( t )
#macro #tc( &1 &2 )
t&1 "&2"
#endmacro
FRAMEELEMENTS = TOTALCOLUMN ABSCOLUMN ABSROW;
TABLETITLE = "Zusammenfassende Darstellung der Totalspalten aus 11 Tabellen(TOTALCOLUMNTABLE)";
TOTALCOLUMNTABLE NAME tc6 = #iter( tc );
TOPTEXT = "In dieser Tabelle sind die Inhalte der Totalspalten der angegebenen Tabellen zusammengetragen.
In einer TOTALCOLUMNTABLE findet keinerlei Zählung statt, sondern die in den ←֓ Ursprungstabellen gedruckten
Texte der Ergebniszellen werden 1:1 übertragen.
";
Beispielhaft seien hier die Tabellen t1 und t8 abgebildet.
Tabellenbeispiel 1
Tabellenbeispiel 2
Die zusammenfassende Tabelle ist hier zu sehen. Die Spalten der Übersichtstabelle sind in der Reihenfolge angeordnet, wie die Tabellen im Statement benannt werden.
Aus den Einzeltabellen mit TOTALCOLUMNTABLE erzeugte Übersicht
Zwar gilt bei Aufruf von TOTALCOLUMNTABLE noch die Voreinstellung FRAMEELEMENTS = TOTALCOLUMN ABSROW; Für TOTALCOLUMNTABLEs kann aber nur eine ABSROW sinnvoll gebildet werden. Weder ABSCOLUMN noch TOTALCOLUMN noch PHYSICALCOLUMN machen Sinn. Eine TOTALROW wäre logisch möglich; da die Tabelle aber aus den einzelnen Textstücken zusammengebaut werden, die den CountCells der Ursprungstabellen entnommen werden, ist es für die Software nur möglich, das CELLELEMENT ABSOLUTE in der Totalzelle der Spalte eindeutig zu erkennen. Im Endeffekt bleibt von allen angeforderten FRAMEELEMENTS also nur ABSROW übrig.
Die Labeltexte und die Sortierung werden aus der ersten Tabelle (in diesem Fall name="t1") entnommen. Es kann aber auch eine andere Tabelle, z.B. die zweite Tabelle, als 'leitende Tabelle' herangezogen werden. Dazu schreibt man im Anschluss an die heranzuziehenden Tabellen und deren Beschriftungen das Schlüsselwort BY und die Ordnungszahl der gewünschten Tabelle, also eine 2 für die zweite Tabelle.
Die Ursprungstabellen (t1 bis t11) könnten auch unterschiedlich sortiert sein. Die Zellen der anderen Spalten bzw. Ursprungstabellen werden den Labelzellen anhand der ausgezählten Codes zugeordnet.
Die Sortierung dieser Totalspalte wird auch für die folgenden Spalten verwendet. Wenn eine TOTALCOLUMNTABLE nach einer anderen Ursprungstabelle sortiert sein soll, kann man dies durch das Keyword BY anfordern. 'BY 3' am Ende des Statements sorgt dafür, dass die resultierende TOTALCOLUMNTABLE genauso sortiert wird wie die dritte Tabelle in der Liste. Die Tabelle 't3' wäre dann in unserem Beispiel die 'leitende Tabelle'.
TotalColumnTable als Grundlage von Grafiken
Die Software hat bei der Konstruktion einer solchen Tabelle keine Kenntnis mehr von der inhaltlichen Bedeutung der einzelnen Zeilen oder Zellen der TOTALCOLUMNTABLE. Das hat natürlich Folgen für die weitere Verwendung solcher Tabellen. Vor allem bei der Verwendung mit GESStabs Artist oder GESS ChartFactory ist es ersichtlich nicht möglich, einzelne CELLELEMENTS anzusprechen. Die Inhalte der Zellen der TOTALCOLUMNTABLE liegen in der Form von HISTORY-Texten vor. Wenn eine TOTALCOLUMNTABLE auf Ursprungstabellen beruht, die mehr als ein CELLELEMENT enthalten, sieht die Chartroutine lediglich einen String, der nacheinander mehrere Zahlen enthält. Die Chartroutinen würden eine Zelle mit solch einem HISTORY-Text als 'numerisch leer' betrachten.
Aber aus einer TOTALCOLUMNTABLE, die nur aus Tabellen mit nur einem CELLELEMENT hervorgehen, lassen sich auch Übersichtscharts erzeugen:
TOTALCOLUMNTABLE aus Tabellen mit nur einem CELLELEMENT
Chart basierend auf TOTALCOLUMNTABLE
Wenn man das Chart so anschaut: die Software hat erkannt, dass die Achse bis 100 nicht ausreicht. Das ergibt sich aus der Rundung der Prozentwerte. Diese stehen ohne Nachkommastellen in der Tabelle, und bei Verarbeitung von HISTORY-basierten Zellen stehen keine weiteren Informationen zur Verfügung. Und weil in der Summe mal 99, mal 100, mal 101 rauskommen, ist der echte Rand des Charts etwas 'krumm'.
Die dazugehörende GESSCHART-Anweisung:
GESSCHART
stacked
CHARTTITLE "Chart basierend auf einer TOTALCOLUMNTABLE"
=
| FORM RECTANGLE
COLUMNS 1:11 ROWS 5 linewidth 0.1 NUMINGRAPH
form rectline linecolor 0 linedash 5
| FORM RECTANGLE
COLUMNS 1:11 ROWS 4 linewidth 0.1 NUMINGRAPH
form rectline linecolor 0 linedash 4
| FORM RECTANGLE
COLUMNS 1:11 ROWS 3 linewidth 1 NUMINGRAPH
form rectline linecolor $ff0000 linedash 3
| FORM RECTANGLE
COLUMNS 1:11 ROWS 2 linewidth 1 NUMINGRAPH
form rectline linecolor 0 linedash 2
| FORM RECTANGLE
COLUMNS 1:11 ROWS 1 linewidth 0.1 NUMINGRAPH
form rectline linecolor 0 linedash 1
;